Ejercicio PSeInt: Calcular horas extras y descuento

Resuelva en el software PSeInt las siguientes problemáticas, basadas en un algoritmo
con decisión doble y compleja:

a.- Doble: “A un trabajador le pagan según sus horas trabajadas y la tarifa está a un valor por hora. Si
la cantidad de horas trabajadas es mayor a 40 horas, la tarifa por hora se incrementa en un 50% para
las horas extras. Calcular el salario del trabajador dadas las horas trabajadas y la tarifa.”

b.- Compleja: “A un trabajador le descuentan de su sueldo el 10% si su sueldo es menor o igual a
1000, por encima de 1000 y hasta 2000 el 5% del adicional, y por encima de 2000 el 3% del adicional.
Calcular el descuento y sueldo neto que recibe el trabajador, dado su sueldo.”


Algoritmo:
________________________________________________________

Proceso salario
   
    //El menu es para dar a elegir la opcion a y b del problema
    Escribir "====> MENU <====";
    Escribir "1 Calcular sueldo por horas trabajadas";
    Escribir "2 Calcular descuento";
   
    Repetir
        Leer a1
        Si a1<>1 y a1<>2 Entonces
            Escribir "Debe ingresar el numero 1 o 2";
        Fin Si
    Hasta Que a1=1 o a1=2
   
    Si a1=1 Entonces
        Escribir "Ingrese las horas trabajadas";
        Leer horas;
        Escribir "Ingrese el valor de una hora de trabajo";
        Leer pr;
       
        Si horas>40 Entonces
            horas2<-horas-40;
            pr1<-40*pr;
            pr2<-horas2*(pr*(150/100));
            prfinal<-pr1+pr2;
        Sino
            prfinal<-pr*horas;
        Fin Si
       
        Escribir "El sueldo es de ", prfinal;
    Sino
        Escribir "Ingrese el sueldo completo";
        leer sueldo;
       
        Si sueldo<=1000 Entonces
            descuento<-sueldo*10/100;
            sueldofinal<-sueldo-descuento;
        Fin Si
       
        Si sueldo>1000 y sueldo<=2000 Entonces
            resto<-sueldo-1000;
            descuento1<-100;
            descuento2<-resto*5/100;
            descuento<-descuento1+descuento2;
            sueldofinal<-sueldo-descuento;
        Fin Si
       
        Si sueldo>2000 Entonces
            resto<-sueldo-2000;
            descuento1<-100;
            descuento2<-50;
            descuento3<-resto*3/100;
            descuento<-descuento1+descuento2+descuento3;
            sueldofinal<-sueldo-descuento;
        Fin Si
       
        Escribir "El descuento es de: ", descuento;
        Escribir "El sueldo neto es de: ", sueldofinal;
    Fin Si
FinProceso